Zsh 入门(安装及使用)

oh-my-zsh国内镜像安装和更新方法

使用技巧

色彩高亮

并不是传统基于正则表达式的色彩高亮，而是真的会判断你输入的是啥的色彩高亮：
image.png
白色代表普通命令或者程序，红色代表错误命令，这个很管用，你再一个个字母的敲命令，前面都是红色的，如果敲对了最后一个字母的话，你会看到整条命令连着前面的都变成了白色，代表你敲对了。以前无高亮的时候敲错了都不知道，还要往上翻着左右检查。下面青色的代表内建命令或者 alias （echo 和 ls ），这些都不是正则判断出来的，是真的去检查的。
细心的人会发现非零的错误码，也会高亮显示在最右边（上一条 data命令错误，返回127）。

命令提示

注意，命令提示和补全是两个完全不同的系统，很多时候提示比补全更有用：
image.png
你才输入完 “tar”命令，后面就用灰色给你提示 tar 命令的参数，而且是随着你动态输入完每一个字母不断修正变化：
image.png
比如你输入到 - 后，没有跟着它上面的提示，而是输入了一个c字母，它马上明白你是要压缩，不是解压，然后随即给出你压缩对应的命令提示。
这个命令提示是基于你的历史命令数据库进行分析的，随着你输入的命令越来越多，提示将会越来越准确和顺手，某些不常输入的命令特别管用，比如偶尔查看下网卡配置：
image.png
刚输入完：cat /etc/n 它后面已经猜出你可能要查看网卡配置了，然后马上给出你提示，用不着你 tab 补全半天，你才敲 gc ，它就猜测出你可能想运行 gcc，然后马上给出完整建议：
image.png
如果你觉得它提示的正确，你可以 CTRL+F 表示采纳，后面就会自动帮你一次性全部输入完了，不用一个字一个字的照着敲。前面的高亮就不说了，用惯这套提示系统，你就再也难以回到光秃秃的 bash 时代了。

智能补全

传统 shell 的补全在 zsh 面前基本都可以下班了：
image.png
即便可以在终端下舒适工作的人，面对有些任务也会觉得烦躁，比如频繁的切换路径，这种缩写路径补全是我用 zsh 的一大痛点之一，特别是路径比较长的时候，比如 OS X 下工具链层层套的那种路径，比如某 java 代码树，有了这种缩写补全，能让你切换路径流畅不少。
当补全内容较多时，不用像 bash 一样持续提示你需要继续输入，也不会像 cmd 永无止境的循环下去，连续敲击两次 TAB 键 zsh 给你一个补全目录，让你上下左右选择：
image.png
这叫选择模式，由两次连续 TAB 进入，进入后，除了 tab/shift+tab 可以前后切换外，你还可以使用光标键上下左右移动，或者使用 emacs 键位：ctrl + f/b/p/n (左右上下：forward, backward, previous, next) 。如果你觉得光标键太远难按，CTRL+f/b/p/n 太伤小拇指，可以跟我一样新定义出一套：ALT+hjkl （左下上右）来选择，十分顺手。回车表示确认选择，用 CTRL+G 表示退出。
命令参数补全更不在话下，输入 svn 后面按 TAB：
image.png
就出现了 svn 的参数，这种一级参数补全基本只会对很少用的命令才有效果，svn/git 这种一级参数基本都不需要补全的，我们一般会需要到二级参数补全，比如已经输入了 svn commit，但是有一个 commit 的参数我忘记了，我只记得两个减号开头的，于是：
image.png
这时候两次 TAB 进入选择模式就比较管用了，svn 的二级参数往往很长，选择模式比如信任 server 那个，选择完回车确认，或者 CTRL+G 退出选择模式。
zsh的补全真的太强了，我这里只说了十分之一不到，没法一一展开了，但就上面几个已经让我有充分的理由切换到 zsh 了。

快速跳转

前面也说过命令行工作中，不同的路径间切来切去是个头疼的问题，除了上面提到的缩写补全外，有无更快的办法让我马上切换到我最近跳转过的某个路径？当然有“cd -”命令：
image.png
输入 cd 后面加一个减号后，按一次 tab 马上就列出本次登陆后去过的最近几次路径，接着根据下面的提示输入数字按回车就过去了，比如输入：
$ cd -5 <回车>
就跳转到 ~/software/libclang-python3 路径下了。当然你还可以不输入数字，而是再按一次 tab 进入选择模式，上下键或者 ctrl+n/p 来选择，回车确认，ctrl+g 返回。

自动跳转

有了前面的路径缩写展开，和这里的最近访问路径切换，你已经没法再回到过去那种按部就班输入路径外加点弱智补全的方式了，但是可能你还会问，能否更进一步，不限于本次登陆或者最近去过的几级路径，有没有办法让我快速进入自我开始用 zsh 之后进入过的某个路径呢？当然可以，我们用 z 命令，查看历史上进入过的目录：
image.png
敲入 z 命令，列出了自从我开始用zsh进入过的目录和他们的权重，进入次数越多，权重越大，便于演示，我删除了我的历史，随便 cd 了一下，保持列表的简洁。z 后面加一个关键词就能跳转到所有匹配的历史路径中权重最高的那个了：
image.png
比如所有历史路径都包含 o ，那么 z o 就会跳转到权重最高的 ~/software 目录中。使用：“z -l foo” 可以列出包含 foo 的所有历史路径：
image.png
比如我们查询包含关键字为 c 的所有历史路径和他们的权重，有时你搞不清楚权重，可能会跳转错了，比如有两个路径：
project1/src project2/src
那么你 z src 的时候可能并不能如你愿跳转到你想要去的路径，那怎么办呢？第一个办法是实际 cd project1/src 过去，增加它的权重，权重超过 project2/src 那么下次 z src 的时候就会跳转过去，你可以实时用 z -l src 查看包含 src 的所有路径权重。
更加可靠的方法是，增加一个关键字，比如 z 1 src ，空格分隔多个关键字，z会先匹配出第一个来，比如1 ，然后再匹配第二个 src ，马上锁定 project1/src 了。大家实际使用起来，一般是 z + 最后一级目录名，比如：
$ z vim # -> /home/skywind/software/vim $ z tmp # -> /home/skywind/tmp $ z local # -> /home/skywind/.local
99%的时候这样做就足够了，当没有按照你要求跳转的时候，你可以再补充一下再上一级目录的一些信息，比如 z vim/src 或者 z v src 都可以，弄不明白会跳转到哪里，可以随时用：
$ z -l key1 [key2 … ]
查看权重。不过常使用你根本必担心这个问题，基本上常去的地方，z 都是指哪打哪。如果说前面的路径缩写展开和最近访问快速切换是火箭的话，z 就是加速燃料了。
熟练的掌握上面几点内容，可让你体验到在终端里溜冰的感觉，再也没有泥里走路的抓狂。

热键绑定

zsh 里面使用 bindkey 命令可以设置一系列热键，用来运行某一个 zsh 内部命令或者某个 shell 命令，谁规定终端只能敲字母呢？我们还可以按热键，比如从网上下载了一个 tar 包解开后要稍微浏览一下里面的内容，用的最多的两条命令是啥呢？第一条是 ls 命令，每到一个子目录都要先按一下，还有就是 cd .. 对吧，经过配置：
bindkey -s ‘\eo’ ‘cd ..\n’ # 按下ALT+O 就执行 cd .. 命令 bindkey -s ‘\e;’ ‘ls -l\n’ # 按下 ALT+; 就执行 ls -l 命令
你还可以设置一键打开编辑器，或者一键帮你输入某常用命令的一部分。除了这些命令外，日常命令编写也可以加强一下：
bindkey ‘\e[1;3D’ backward-word # ALT+左键：向后跳一个单词 bindkey ‘\e[1;3C’ forward-word # ALT+右键：前跳一个单词 bindkey ‘\e[1;3A’ beginning-of-line # ALT+上键：跳到行首 bindkey ‘\e[1;3B’ end-of-line # ALT+下键：调到行尾
敲命令时经常需要对已有命令进行修改，默认一个字符一个字符的跳太慢了，这样设置以后基于单词的跳转快速很多，配合其他一些快捷键，修改命令事半功倍。
终端下从 v220t 到 xterm 规范里，按下 alt+x 会先发送一个8位 ASCII 码 27，即 ESC键的扫描吗，然后跟着 x 这个字符，也等价于快速（比如100毫秒内）前后按下 ESC 和 x。
还不会再自己的终端软件里设置允许 alt 键的同学们可以搜索下相关文章。

如何配置？

zsh 有多强呢？上面说的这些和我平时用的功能可能只发挥了 zsh 10% 不到的能力，我也并不是什么 zsh 专家或者脚本高手，上面所讲的五点内容对于 zsh 的全部功能来讲可能都只用到了 zsh 的九牛一毛，但是以上五点只要有一条，就已经够我放弃其他 shell 来尝试一下了。
那最后上面这些功能怎么配置的？眼熟的人应该发现这不是默认的 oh-my-zsh 框架，这只是我写的一个 100 多行的 .zshrc 小脚本，如果你想体验一下的话，可以先 apt-get 安装一下 zsh，然后打开：
把上面这个配置的内容复制粘贴到你的 ~/.zshrc 文件里，保存，运行 zsh 即可。头一次运行会安装一些依赖包，稍等两分钟，以后再进入就瞬间进入了。

  1. #color{{{
  2. autoload colors
  3. colors
  5. for color in RED GREEN YELLOW BLUE MAGENTA CYAN WHITE; do
  6. eval _$color='%{$terminfo[bold]$fg[${(L)color}]%}'
  7. eval $color='%{$fg[${(L)color}]%}'
  8. (( count = $count + 1 ))
  9. done
  10. FINISH="%{$terminfo[sgr0]%}"
  11. #}}}
  13. #命令提示符
  14. RPROMPT=$(echo "$RED%D %T$FINISH")
  15. PROMPT=$(echo "$CYAN%n@$YELLOW%M:$GREEN%/$_YELLOW>$FINISH ")
  17. #PROMPT=$(echo "$BLUE%M$GREEN%/
  18. #$CYAN%n@$BLUE%M:$GREEN%/$_YELLOW>>>$FINISH ")
  19. #标题栏、任务栏样式{{{
  20. case $TERM in (*xterm*|*rxvt*|(dt|k|E)term)
  21. precmd () { print -Pn "\e]0;%n@%M//%/\a" }
  22. preexec () { print -Pn "\e]0;%n@%M//%/\ $1\a" }
  23. ;;
  24. esac
  25. #}}}
  27. #编辑器
  28. export EDITOR=vim
  29. #输入法
  30. export XMODIFIERS="@im=ibus"
  31. export QT_MODULE=ibus
  32. export GTK_MODULE=ibus
  33. #关于历史纪录的配置 {{{
  34. #历史纪录条目数量
  35. export HISTSIZE=10000
  36. #注销后保存的历史纪录条目数量
  37. export SAVEHIST=10000
  38. #历史纪录文件
  39. export HISTFILE=~/.zhistory
  40. #以附加的方式写入历史纪录
  41. setopt INC_APPEND_HISTORY
  42. #如果连续输入的命令相同，历史纪录中只保留一个
  43. setopt HIST_IGNORE_DUPS
  44. #为历史纪录中的命令添加时间戳
  45. setopt EXTENDED_HISTORY      
  47. #启用 cd 命令的历史纪录，cd -[TAB]进入历史路径
  48. setopt AUTO_PUSHD
  49. #相同的历史路径只保留一个
  50. setopt PUSHD_IGNORE_DUPS
  52. #在命令前添加空格，不将此命令添加到纪录文件中
  53. #setopt HIST_IGNORE_SPACE
  54. #}}}
  56. #每个目录使用独立的历史纪录{{{
  57. cd() {
  58. builtin cd "$@"                             # do actual cd
  59. fc -W                                       # write current history  file
  60. local HISTDIR="$HOME/.zsh_history$PWD"      # use nested folders for history
  61. if  [ ! -d "$HISTDIR" ] ; then          # create folder if needed
  62. mkdir -p "$HISTDIR"
  63. fi
  64. export HISTFILE="$HISTDIR/zhistory"     # set new history file
  65. touch $HISTFILE
  66. local ohistsize=$HISTSIZE
  67. HISTSIZE=0                              # Discard previous dir's history
  68. HISTSIZE=$ohistsize                     # Prepare for new dir's history
  69. fc -R                                       #read from current histfile
  70. }
  71. mkdir -p $HOME/.zsh_history$PWD
  72. export HISTFILE="$HOME/.zsh_history$PWD/zhistory"
  74. function allhistory { cat $(find $HOME/.zsh_history -name zhistory) }
  75. function convhistory {
  76. sort $1 | uniq |
  77. sed 's/^:\([ 0-9]*\):[0-9]*;\(.*\)/\1::::::\2/' |
  78. awk -F"::::::" '{ $1=strftime("%Y-%m-%d %T",$1) "|"; print }'
  79. }
  80. #使用 histall 命令查看全部历史纪录
  81. function histall { convhistory =(allhistory) |
  82. sed '/^.\{20\} *cd/i\\' }
  83. #使用 hist 查看当前目录历史纪录
  84. function hist { convhistory $HISTFILE }
  86. #全部历史纪录 top50
  87. function top50 { allhistory | awk -F':[ 0-9]*:[0-9]*;' '{ $1="" ; print }' | sed 's/ /\n/g' | sed '/^$/d' | sort | uniq -c | sort -nr | head -n 50 }
  89. #}}}
  91. #杂项 {{{
  92. #允许在交互模式中使用注释  例如：
  93. #cmd #这是注释
  94. setopt INTERACTIVE_COMMENTS      
  96. #启用自动 cd，输入目录名回车进入目录
  97. #稍微有点混乱，不如 cd 补全实用
  98. setopt AUTO_CD
  100. #扩展路径
  101. #/v/c/p/p => /var/cache/pacman/pkg
  102. setopt complete_in_word
  104. #禁用 core dumps
  105. limit coredumpsize 0
  107. #Emacs风格 键绑定
  108. bindkey -e
  109. #bindkey -v
  110. #设置 [DEL]键 为向后删除
  111. #bindkey "\e[3~" delete-char
  113. #以下字符视为单词的一部分
  114. WORDCHARS='*?_-[]~=&;!#$%^(){}<>'
  115. #}}}
  117. #自动补全功能 {{{
  118. setopt AUTO_LIST
  119. setopt AUTO_MENU
  120. #开启此选项，补全时会直接选中菜单项
  121. #setopt MENU_COMPLETE
  123. autoload -U compinit
  124. compinit
  126. #自动补全缓存
  127. #zstyle ':completion::complete:*' use-cache on
  128. #zstyle ':completion::complete:*' cache-path .zcache
  129. #zstyle ':completion:*:cd:*' ignore-parents parent pwd
  131. #自动补全选项
  132. zstyle ':completion:*' verbose yes
  133. zstyle ':completion:*' menu select
  134. zstyle ':completion:*:*:default' force-list always
  135. zstyle ':completion:*' select-prompt '%SSelect:  lines: %L  matches: %M  [%p]'
  137. zstyle ':completion:*:match:*' original only
  138. zstyle ':completion::prefix-1:*' completer _complete
  139. zstyle ':completion:predict:*' completer _complete
  140. zstyle ':completion:incremental:*' completer _complete _correct
  141. zstyle ':completion:*' completer _complete _prefix _correct _prefix _match _approximate
  143. #路径补全
  144. zstyle ':completion:*' expand 'yes'
  145. zstyle ':completion:*' squeeze-shlashes 'yes'
  146. zstyle ':completion::complete:*' '\\'
  148. #彩色补全菜单
  149. eval $(dircolors -b)
  150. export ZLSCOLORS="${LS_COLORS}"
  151. zmodload zsh/complist
  152. zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
  153. zstyle ':completion:*:*:kill:*:processes' list-colors '=(#b) #([0-9]#)*=0=01;31'
  155. #修正大小写
  156. zstyle ':completion:*' matcher-list '' 'm:{a-zA-Z}={A-Za-z}'
  157. #错误校正
  158. zstyle ':completion:*' completer _complete _match _approximate
  159. zstyle ':completion:*:match:*' original only
  160. zstyle ':completion:*:approximate:*' max-errors 1 numeric
  162. #kill 命令补全
  163. compdef pkill=kill
  164. compdef pkill=killall
  165. zstyle ':completion:*:*:kill:*' menu yes select
  166. zstyle ':completion:*:*:*:*:processes' force-list always
  167. zstyle ':completion:*:processes' command 'ps -au$USER'
  169. #补全类型提示分组
  170. zstyle ':completion:*:matches' group 'yes'
  171. zstyle ':completion:*' group-name ''
  172. zstyle ':completion:*:options' description 'yes'
  173. zstyle ':completion:*:options' auto-description '%d'
  174. zstyle ':completion:*:descriptions' format $'\e[01;33m -- %d --\e[0m'
  175. zstyle ':completion:*:messages' format $'\e[01;35m -- %d --\e[0m'
  176. zstyle ':completion:*:warnings' format $'\e[01;31m -- No Matches Found --\e[0m'
  177. zstyle ':completion:*:corrections' format $'\e[01;32m -- %d (errors: %e) --\e[0m'
  179. # cd ~ 补全顺序
  180. zstyle ':completion:*:-tilde-:*' group-order 'named-directories' 'path-directories' 'users' 'expand'
  181. #}}}
  183. ##行编辑高亮模式 {{{
  184. # Ctrl+@ 设置标记，标记和光标点之间为 region
  185. zle_highlight=(region:bg=magenta #选中区域
  186. special:bold      #特殊字符
  187. isearch:underline)#搜索时使用的关键字
  188. #}}}
  190. ##空行(光标在行首)补全 "cd " {{{
  191. user-complete(){
  192. case $BUFFER in
  193. "" )                       # 空行填入 "cd "
  194. BUFFER="cd "
  195. zle end-of-line
  196. zle expand-or-complete
  197. ;;
  198. "cd --" )                  # "cd --" 替换为 "cd +"
  199. BUFFER="cd +"
  200. zle end-of-line
  201. zle expand-or-complete
  202. ;;
  203. "cd +-" )                  # "cd +-" 替换为 "cd -"
  204. BUFFER="cd -"
  205. zle end-of-line
  206. zle expand-or-complete
  207. ;;
  208. * )
  209. zle expand-or-complete
  210. ;;
  211. esac
  212. }
  213. zle -N user-complete
  214. bindkey "\t" user-complete
  215. #}}}
  217. ##在命令前插入 sudo {{{
  218. #定义功能
  219. sudo-command-line() {
  220. [[ -z $BUFFER ]] && zle up-history
  221. [[ $BUFFER != sudo\ * ]] && BUFFER="sudo $BUFFER"
  222. zle end-of-line                 #光标移动到行末
  223. }
  224. zle -N sudo-command-line
  225. #定义快捷键为： [Esc] [Esc]
  226. bindkey "\e\e" sudo-command-line
  227. #}}}
  229. #命令别名 {{{
  230. alias cp='cp -i'
  231. alias mv='mv -i'
  232. alias rm='rm -i'
  233. alias ls='ls -F --color=auto'
  234. alias ll='ls -al'
  235. alias grep='grep --color=auto'
  236. alias la='ls -a'
  237. alias pacman='sudo pacman-color'
  238. alias p='sudo pacman-color'
  239. alias y='yaourt'
  240. alias h='htop'
  241. alias vim='sudo vim'
  243. #[Esc][h] man 当前命令时，显示简短说明
  244. alias run-help >&/dev/null && unalias run-help
  245. autoload run-help
  247. #历史命令 top10
  248. alias top10='print -l  ${(o)history%% *} | uniq -c | sort -nr | head -n 10'
  249. #}}}
  251. #路径别名 {{{
  252. #进入相应的路径时只要 cd ~xxx
  253. hash -d A="/media/ayu/dearest"
  254. hash -d H="/media/data/backup/ayu"
  255. hash -d E="/etc/"
  256. hash -d D="/home/ayumi/Documents"
  257. #}}}
  259. ##for Emacs {{{
  260. #在 Emacs终端 中使用 Zsh 的一些设置 不推荐在 Emacs 中使用它
  261. #if [[ "$TERM" == "dumb" ]]; then
  262. #setopt No_zle
  263. #PROMPT='%n@%M %/
  264. #>>'
  265. #alias ls='ls -F'
  266. #fi
  267. #}}}
  269. #{{{自定义补全
  270. #补全 ping
  271. zstyle ':completion:*:ping:*' hosts 192.168.1.{1,50,51,100,101} www.google.com
  273. #补全 ssh scp sftp 等
  274. #zstyle -e ':completion::*:*:*:hosts' hosts 'reply=(${=${${(f)"$(cat {/etc/ssh_,~/.ssh/known_}hosts(|2)(N) /dev/null)"}%%[# ]*}//,/ })'
  275. #}}}
  277. #{{{ F1 计算器
  278. arith-eval-echo() {
  279. LBUFFER="${LBUFFER}echo \$(( "
  280. RBUFFER=" ))$RBUFFER"
  281. }
  282. zle -N arith-eval-echo
  283. bindkey "^[[11~" arith-eval-echo
  284. #}}}
  286. ####{{{
  287. function timeconv { date -d @$1 +"%Y-%m-%d %T" }
  289. # }}}
  291. zmodload zsh/mathfunc
  292. autoload -U zsh-mime-setup
  293. zsh-mime-setup
  294. setopt EXTENDED_GLOB
  295. #autoload -U promptinit
  296. #promptinit
  297. #prompt redhat
  299. setopt correctall
  300. autoload compinstall
  302. #漂亮又实用的命令高亮界面
  303. setopt extended_glob
  304.  TOKENS_FOLLOWED_BY_COMMANDS=('|' '||' ';' '&' '&&' 'sudo' 'do' 'time' 'strace')
  306.  recolor-cmd() {
  307.      region_highlight=()
  308.      colorize=true
  309.      start_pos=0
  310.      for arg in ${(z)BUFFER}; do
  311.          ((start_pos+=${#BUFFER[$start_pos+1,-1]}-${#${BUFFER[$start_pos+1,-1]## #}}))
  312.          ((end_pos=$start_pos+${#arg}))
  313.          if $colorize; then
  314.              colorize=false
  315.              res=$(LC_ALL=C builtin type $arg 2>/dev/null)
  316.              case $res in
  317.                  *'reserved word'*)   style="fg=magenta,bold";;
  318.                  *'alias for'*)       style="fg=cyan,bold";;
  319.                  *'shell builtin'*)   style="fg=yellow,bold";;
  320.                  *'shell function'*)  style='fg=green,bold';;
  321.                  *"$arg is"*)
  322.                      [[ $arg = 'sudo' ]] && style="fg=red,bold" || style="fg=blue,bold";;
  323.                  *)                   style='none,bold';;
  324.              esac
  325.              region_highlight+=("$start_pos $end_pos $style")
  326.          fi
  327.          [[ ${${TOKENS_FOLLOWED_BY_COMMANDS[(r)${arg//|/\|}]}:+yes} = 'yes' ]] && colorize=true
  328.          start_pos=$end_pos
  329.      done
  330.  }
  331. check-cmd-self-insert() { zle .self-insert && recolor-cmd }
  332.  check-cmd-backward-delete-char() { zle .backward-delete-char && recolor-cmd }
  334.  zle -N self-insert check-cmd-self-insert
  335.  zle -N backward-delete-char check-cmd-backward-delete-char