FIDL语法

英文原文快照

经修改的BNF规则

下文描述的是FIDL源文件的语法，语法使用经修改的BNF格式表示。

非终结符号由逗号分隔的其他符号序列来表示。

  1. nonterminal = list , of , symbols ;

有些符号是终止符号，它们要么是全部大写，要么是用双引号括起来。

  1. another-nonterminal = THESE , ARE , TERMINALS , AND , SO , IS , "this" ;

或者由管道的形式来表示。

  1. choice = this | that | the-other ;

用括号表示选项（0或1）。

  1. optional = ( maybe , these ) , but , definitely , these ;

重复（0或多个）可用括号和星号表示。

  1. zero-or-more = ( list-part )* ;

另外，重复（1或多个）还可用括号和加号表示。

  1. one-or-more = ( list-part )+ ;

符号

在lex处理期间将忽略空格和注释，因此不会出现在后续的语法中，其中注释采用的是C++样式——//直到行尾。

TODO(US-238)：最终注释将作为文档生成系统的一部分，使其变得可读。

语法

file是FIDL文档入口符号。

  1. file = library-header , using-list , declaration-list ;
  3. library-header = ( attribute-list ) , "library" , compound-identifier , ";" ;
  5. using-list = ( using | using-declaration )* ;
  7. using-declaration = "using" , IDENTIFIER ,  "=" , primitive-type , ";" ;
  9. declaration-list = ( declaration , ";" )* ;
  11. compound-identifier = IDENTIFIER ( "." , IDENTIFIER )* ;
  13. using = "using" , compound-identifier , ( "as" , IDENTIFIER ) , ";" ;
  15. declaration = const-declaration | enum-declaration | interface-declaration |
  16.               struct-declaration | union-declaration ;
  18. const-declaration = ( attribute-list ) , "const" , type , IDENTIFIER , "=" , constant ;
  20. enum-declaration = ( attribute-list ) , "enum" , IDENTIFIER , ( ":" , integer-type ) ,
  21.                    "{" , ( enum-member , ";" )+ , "}" ;
  23. enum-member = IDENTIFIER , ( "=" , enum-member-value ) ;
  25. enum-member-value = IDENTIFIER | NUMERIC-LITERAL ;
  27. interface-declaration = ( attribute-list ) , "interface" , IDENTIFIER ,
  28.                         ( ":" , super-interface-list ) , "{" , ( interface-method , ";" )*  , "}" ;
  30. super-interface-list = compound-identifier
  31.                      | compound-identifier , "," , super-interface-list
  33. interface-method = ordinal , ":" , interface-parameters
  35. interface-parameters = IDENTIFIER , parameter-list , ( "->" , parameter-list )
  36.                      | "->" , IDENTIFIER , parameter-list
  38. parameter-list = "(" , parameters , ")" ;
  40. parameters = parameter | parameter , "," , parameter-list ;
  42. parameter = type , IDENTIFIER ;
  44. struct-declaration = ( attribute-list ) , "struct" , IDENTIFIER , "{" , ( struct-field , ";" )* , "}" ;
  46. struct-field = type , IDENTIFIER , ( "=" , constant ) ;
  48. union-declaration = ( attribute-list ) , "union" , IDENTIFIER , "{" , ( union-field , ";" )+ , "}" ;
  50. union-field = type , IDENTIFIER ;
  52. attribute-list = "[" , attributes, "]" ;
  54. attributes = attribute | attribute , "," , attribute ;
  56. attribute = IDENTIFIER , ( "=", STRING-LITERAL ) ;
  58. type = identifier-type | array-type | vector-type | string-type | handle-type
  59.                        | request-type | primitive-type ;
  61. identifier-type = compound-identifier , ( "?" ) ;
  63. array-type = "array" , "<" , type , ">" , ":" , constant ;
  65. vector-type = "vector" , "<" , type , ">" , ( ":" , constant ) , ( "?" ) ;
  67. string-type = "string" , ( ":" , constant ) , ( "?" ) ;
  69. handle-type = "handle" , ( "<" , handle-subtype , ">" ) , ( "?" ) ;
  71. handle-subtype = "process" | "thread" | "vmo" | "channel" | "event" | "port" |
  72.                  "interrupt" | "log" | "socket" | "resource" | "eventpair" |
  73.                  "job" | "vmar" | "fifo" | "guest" | "timer" ;
  75. request-type = "request" , "<" , compound-identifier , ">" , ( "?" ) ;
  77. primitive-type = integer-type | "bool" | "float32" | "float64" ;
  79. integer-type = "int8" | "int16" | "int32" | "int64" |
  80.                "uint8" | "uint16" | "uint32" | "uint64" ;
  82. constant = compound-identifier | literal ;
  84. ordinal = NUMERIC-LITERAL ;
  86. literal = STRING-LITERAL | NUMERIC-LITERAL | TRUE | FALSE ;