前言：有同事在项目上遇到一个需求，需要将打印的SmartForms保存为PDF。在标准的事务码PDF!里面有实现相应的功能，但是文件名和路径不能自定义，不能满足客户的要求，我听了，觉得有趣，于是决定研究下，通过debug发现，标准事务码PDF!是调用了几个函数将表单数据进行了转换，然后输出为PDF的，只是几个函数之间的调用，实现起来相对来说比较简单，于是写了个Demo作为研究记录，在这里展示下。

实现步骤演示：

1.创建SmartForms Demo结构

1.将SmartForms保存为PDF - 图1

2.绘制SmartForms表单对象

1.将SmartForms保存为PDF - 图2

这里为了节省时间，就没有对表单做样式调整。

3.代码实现

  1. *&---------------------------------------------------------------------*
  2. *& Report ZDEMO_SF2PDF
  3. *&---------------------------------------------------------------------*
  4. *&
  5. *&---------------------------------------------------------------------*
  6. REPORT zdemo_sf2pdf.
  7. **********************************************************************
  8. * PROGRAM DETAIL                                                     *
  9. **********************************************************************
  10. * --T-CODE:ZDEMO_SF2PDF
  11. * --AUTHOR:秋の夕
  12. * --CREATE DATE:18.12.2021 13:33:46
  13. * --DESCRIBLE: SmartForm转PDF案例
  14. **********************************************************************
  15. * EDIT LOG                                                           *
  16. **********************************************************************
  17. * VERSION          DATE              AUTHOR           REMARK
  18. * <DEVK90XXX>     <YYYY/MM/DD>       <...>            <REASON>
  20. **********************************************************************
  21. * DECLARATIONS                                                       *
  22. **********************************************************************
  23. *TABLES: .
  24. *
  25. *CONSTANTS: .
  26. *
  27. *TYPES: .
  29. DATA:gt_data   TYPE TABLE OF zstest01.
  30. DATA:l_fm_name TYPE rs38l_fnam,
  31.      ssf_name  TYPE tdsfname.
  32. **********************************************************************
  33. * SELECTION SCREEN                                                   *
  34. **********************************************************************
  35. *  SELECTION-SCREEN: BEGIN OF BLOCK b1 WITH FRAME TITLE TEXT-001.
  36. *    PARAMETERS: .
  37. *
  38. *    SELECT-OPTIONS: .
  39. *
  40. *  SELECTION-SCREEN: END OF BLOCK b1.
  44. **********************************************************************
  45. * INITIALIZATION                                                     *
  46. **********************************************************************
  47. INITIALIZATION.
  48.   ssf_name = 'ZSFTEST01'.         "SmartForms对象名"
  50.   gt_data = VALUE #(              "测试数据"
  51.   ( zid = 1 zname = '测试1')
  52.   ( zid = 2 zname = '测试2')
  53.   ( zid = 3 zname = '测试3')
  54.   ( zid = 4 zname = '测试4')
  55.   ( zid = 5 zname = '测试5')
  56.   ).
  58. **********************************************************************
  59. * AT SELECTION SCREEN                                                *
  60. **********************************************************************
  61. AT SELECTION-SCREEN.
  64. **********************************************************************
  65. * TOP OF PAGE                                                        *
  66. **********************************************************************
  67. TOP-OF-PAGE.
  70. **********************************************************************
  71. * END OF PAGE                                                        *
  72. **********************************************************************
  73. END-OF-PAGE.
  76. **********************************************************************
  77. * AT USER COMMAND                                                    *
  78. **********************************************************************
  79. AT USER-COMMAND.
  82. **********************************************************************
  83. * START OF SELECTION                                                 *
  84. **********************************************************************
  85. START-OF-SELECTION.
  87.   PERFORM frm_sf_to_pdf USING ssf_name.  "转PDF"
  89. **********************************************************************
  90. * END OF SELECTION                                                   *
  91. **********************************************************************
  92. END-OF-SELECTION.
  95. **********************************************************************
  96. * FORMS DECLARATIONS                                                 *
  97. **********************************************************************
  98. *&---------------------------------------------------------------------*
  99. *& Form frm_sf_to_pdf
  100. *&---------------------------------------------------------------------*
  101. *& text
  102. *&---------------------------------------------------------------------*
  103. *&      --> P_FNAME
  104. *&---------------------------------------------------------------------*
  105. FORM frm_sf_to_pdf  USING uv_fname TYPE tdsfname.
  106.   DATA:
  107.     ls_output_opt      TYPE          ssfcompop,
  108.     ls_ctrl_form       TYPE          ssfctrlop,
  109.     lv_user_settings   TYPE          c,
  110.     ls_job_output_info TYPE          ssfcrescl,
  111.     lv_pdf_len         TYPE          i,
  112.     lt_pdf_lines       TYPE TABLE OF tline.
  113.   DATA:lv_path      TYPE string,
  114.        lv_full_path TYPE string,
  115.        lv_filename  TYPE string.
  117.   ls_output_opt-tdnewid = 'X'.                 "设置属性参数"
  118.   ls_output_opt-tdimmed = 'X'.
  119.   ls_output_opt-tddelete = 'X'.
  120.   ls_output_opt-tdlifetime = 'X'.
  121.   ls_output_opt-tddest = 'LP01'.
  122.   ls_output_opt-tdprinter = 'CNSAPWIN'.
  123.   ls_output_opt-xsfformat = 'X'.
  124.   ls_ctrl_form-no_dialog = 'X'.                "必要"
  125.   ls_ctrl_form-preview = 'X'.
  126.   ls_ctrl_form-getotf = 'X'.                   "必要"
  127.   ls_ctrl_form-device = 'PRINTER'.
  128.   lv_user_settings = 'X'.
  131.   CALL FUNCTION 'SSF_FUNCTION_MODULE_NAME'
  132.     EXPORTING
  133.       formname           = uv_fname
  134. *     VARIANT            = ' '
  135.       direct_call        = 'X'
  136.     IMPORTING
  137.       fm_name            = l_fm_name
  138.     EXCEPTIONS
  139.       no_form            = 1
  140.       no_function_module = 2
  141.       OTHERS             = 3.
  143. * 获取OTF数据
  144.   IF sy-subrc = 0.
  145.     CALL FUNCTION l_fm_name
  146.       EXPORTING
  147.         control_parameters = ls_ctrl_form
  148.         output_options     = ls_output_opt
  149.         user_settings      = lv_user_settings
  150.       IMPORTING
  151.         job_output_info    = ls_job_output_info
  152.       TABLES
  153.         i_tab              = gt_data
  154.       EXCEPTIONS
  155.         formatting_error   = 1
  156.         internal_error     = 2
  157.         send_error         = 3
  158.         user_canceled      = 4.
  159.     IF sy-subrc <> 0.
  160.       MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
  161.       WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  162.     ENDIF.
  164. *   转为二进制
  165.     CALL FUNCTION 'CONVERT_OTF'
  166.       EXPORTING
  167.         format                = 'PDF'
  168. *       max_linewidth         = 132
  169.       IMPORTING
  170.         bin_filesize          = lv_pdf_len
  171.       TABLES
  172.         otf                   = ls_job_output_info-otfdata[]
  173.         lines                 = lt_pdf_lines
  174.       EXCEPTIONS
  175.         err_max_linewidth     = 1
  176.         err_format            = 2
  177.         err_conv_not_possible = 3
  178.         err_bad_otf           = 4
  179.         OTHERS                = 5.
  180.     IF sy-subrc <> 0.
  181.       MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
  182.       WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  183.     ENDIF.
  184.     "初始化文件名"
  185.     lv_filename = 'ZDEMO_SF2PDF_' && sy-datum && sy-uzeit && '.PDF'.
  187.     CALL METHOD cl_gui_frontend_services=>get_desktop_directory
  188.       CHANGING
  189.         desktop_directory    = lv_path
  190.       EXCEPTIONS
  191.         cntl_error           = 1
  192.         error_no_gui         = 2
  193.         not_supported_by_gui = 3
  194.         OTHERS               = 4.
  196.     IF sy-subrc = 0.
  197.       CALL METHOD cl_gui_cfw=>flush .
  198.       " 用户选择名称、路径
  199.       CALL METHOD cl_gui_frontend_services=>file_save_dialog
  200.         EXPORTING
  201. *         window_title         = '指定保存文件名'
  202. *         default_extension    = 'XLSX'
  203.           default_file_name    = lv_filename
  204. *         file_filter          = filetype
  205.           initial_directory    = lv_path
  206.           prompt_on_overwrite  = 'X'
  207.         CHANGING
  208.           filename             = lv_filename
  209.           path                 = lv_path
  210.           fullpath             = lv_full_path
  211. *         USER_ACTION          =
  212. *         FILE_ENCODING        =
  213.         EXCEPTIONS
  214.           cntl_error           = 1
  215.           error_no_gui         = 2
  216.           not_supported_by_gui = 3
  217.           OTHERS               = 4.
  219.       IF sy-subrc <> 0.
  220.         MESSAGE | 获取文件路径失败！| TYPE 'S' DISPLAY LIKE 'E'.
  221.       ENDIF.
  222.     ELSE.
  223.       MESSAGE | 用户取消操作！| TYPE 'S' DISPLAY LIKE 'E'.
  224.     ENDIF.
  227. *    CONCATENATE  lv_full_path '.PDF' INTO lv_full_path.
  228. *     DOWNLOAD PDF
  229.     CALL FUNCTION 'GUI_DOWNLOAD'
  230.       EXPORTING
  231.         bin_filesize            = lv_pdf_len
  232.         filename                = lv_full_path
  233.         filetype                = 'BIN'
  234.       TABLES
  235.         data_tab                = lt_pdf_lines
  236.       EXCEPTIONS
  237.         file_write_error        = 1
  238.         no_batch                = 2
  239.         gui_refuse_filetransfer = 3
  240.         invalid_type            = 4
  241.         no_authority            = 5
  242.         unknown_error           = 6
  243.         header_not_allowed      = 7
  244.         separator_not_allowed   = 8
  245.         filesize_not_allowed    = 9
  246.         header_too_long         = 10
  247.         dp_error_create         = 11
  248.         dp_error_send           = 12
  249.         dp_error_write          = 13
  250.         unknown_dp_error        = 14
  251.         access_denied           = 15
  252.         dp_out_of_memory        = 16
  253.         disk_full               = 17
  254.         dp_timeout              = 18
  255.         file_not_found          = 19
  256.         dataprovider_exception  = 20
  257.         control_flush_error     = 21
  258.         OTHERS                  = 22.
  259.   ENDIF.
  260. ENDFORM.

4.实现效果

1.将SmartForms保存为PDF - 图3
1.将SmartForms保存为PDF - 图4

以上就是SmartForms转PDF的简单实现了，感兴趣的小伙伴可以自己去尝试下。