案例:实现ALV——编辑库存地点字段提供搜索帮助.

代码实现步骤:

1.设置LGORT字段编辑及F4属性

  1.     CLEAR gs_fieldcat.
  2.     gs_fieldcat-edit = 'X'.        "ALV字段可编辑"
  3.     gs_fieldcat-f4availabl = 'X'.  "ALV字段F4帮助"
  4.     MODIFY gt_fieldcat FROM gs_fieldcat TRANSPORTING edit f4availabl
  5.     WHERE fieldname = 'LGORT' .

2.定义需要的参数变量

  1. DATA: gt_event    TYPE slis_t_event.     "ALV事件参数"
  2. DATA: stbl        TYPE lvc_s_stbl,         "ALV屏幕刷新参数
  3.       g_grid      TYPE REF TO cl_gui_alv_grid.    "ALV容器对象

3.定义ALV实例类及F4方法

  1. *----------------------------------------------------------------------*
  2. *       CLASS lcl_event_handler DEFINITION
  3. *----------------------------------------------------------------------*
  4. *       类定义 && F4方法声明
  5. *----------------------------------------------------------------------*
  6. CLASS lcl_event_handler DEFINITION."类定义
  7.   PUBLIC SECTION.
  8.     METHODS:
  9. *     F4搜索帮助事件
  10.       handle_f4 FOR EVENT onf4 OF cl_gui_alv_grid
  11.         IMPORTING e_fieldname
  12.                   es_row_no
  13.                   er_event_data
  14.                   et_bad_cells.
  15. ENDCLASS. "lcl_event_handler DEFINITION
  18. *----------------------------------------------------------------------*
  19. *       CLASS lcl_event_handler IMPLEMENTATION
  20. *----------------------------------------------------------------------*
  21. *       类实现 && F4方法实现
  22. *----------------------------------------------------------------------*
  23. CLASS lcl_event_handler IMPLEMENTATION."类实现
  24.   METHOD:handle_f4.
  25. *     窗口时间参数的自定义f4检索帮助
  26.     CASE e_fieldname.
  27.       WHEN 'LGORT'.   "内表字段名称
  28.         PERFORM f4_help_lgort USING e_fieldname
  29.                                     es_row_no.
  30.         er_event_data->m_event_handled = 'X'.
  31.     ENDCASE.
  32. *     设置后，alv稳定刷新
  33.     stbl-row = 'X'." 基于行的稳定刷新
  34.     stbl-col = 'X'." 基于列稳定刷新
  35.     CALL METHOD g_grid->refresh_table_display
  36.       EXPORTING
  37.         is_stable = stbl.
  38.   ENDMETHOD.                    "HANDLE_F4
  39. ENDCLASS. "lcl_event_handler IMPLEMENTATION

4.注册事件

  1. *&---------------------------------------------------------------------*
  2. *& Form frm_display_alv
  3. *&---------------------------------------------------------------------*
  4. *& ALV展示函数
  5. *&---------------------------------------------------------------------*
  6. FORM frm_display_alv .
  7. * 在调用ALV函数之前，将事件注册到事件参数里面。
  8.   APPEND VALUE #( name = 'CALLER_EXIT' form = 'FRM_REGISTER_EVENTS' ) TO gt_event.
  10.   CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY_LVC'
  11.     EXPORTING
  12.       i_callback_program       = sy-repid
  13.       i_callback_pf_status_set = 'SET_PF_STATUS'
  14.       i_callback_user_command  = 'ALV_USER_COMMAND'
  15.       is_layout_lvc            = gs_layout
  16.       it_fieldcat_lvc          = gt_fieldcat
  17.       it_events                = gt_event
  18.       i_save                   = 'A'
  19.     TABLES
  20.       t_outtab                 = gt_output
  21.     EXCEPTIONS
  22.       program_error            = 1
  23.       OTHERS                   = 2.
  25. ENDFORM.

5.实现注册事件内容

  1. *&---------------------------------------------------------------------*
  2. *&      Form  register_events
  3. *&---------------------------------------------------------------------*
  4. *       注册事件
  5. *----------------------------------------------------------------------
  6. FORM frm_register_events USING e_grid TYPE slis_data_caller_exit.
  7.   DATA:lt_f4 TYPE  lvc_t_f4,
  8.        ls_f4 TYPE  lvc_s_f4.
  10.   CALL FUNCTION 'GET_GLOBALS_FROM_SLVC_FULLSCR'
  11.     IMPORTING
  12.       e_grid = g_grid.
  13. *
  14.   DATA: gr_event_handler TYPE REF TO lcl_event_handler.
  15.   CREATE OBJECT gr_event_handler.
  17. * 如果有多个字段需要搜素帮助，以同样方式插入数据      
  18.   ls_f4-fieldname = 'LGORT'.  
  19.   ls_f4-register   = 'X'.
  20.   ls_f4-getbefore  = 'X'.
  21.   ls_f4-chngeafter = 'X'.
  22.   INSERT ls_f4 INTO TABLE lt_f4.
  24. * 注册F4帮助事件
  25.   SET HANDLER gr_event_handler->handle_f4 FOR g_grid.
  26.   CALL METHOD g_grid->register_f4_for_fields
  27.     EXPORTING
  28.       it_f4 = lt_f4.
  29. ENDFORM. "register_events

6.实现F4子程序块

  1. *&---------------------------------------------------------------------*
  2. *& Form f4_help_route
  3. *&---------------------------------------------------------------------*
  4. *& ROUTE搜索帮助
  5. *&---------------------------------------------------------------------*
  6. FORM f4_help_route  USING   p_fieldname TYPE lvc_fname
  7.                              p_row_no TYPE lvc_s_roid.
  8.   DATA: lt_return TYPE STANDARD TABLE OF ddshretval,
  9.         ls_return TYPE ddshretval.
  10. * 获取ALV上点击的行数据
  11.   READ TABLE gt_output ASSIGNING <fs_opt> INDEX p_row_no-row_id.
  13.   IF p_fieldname = 'LGORT'.
  14.     SELECT lgort,lgobe INTO TABLE @DATA(lt_t001l) FROM t001l .
  15.     SORT lt_t001l BY lgort.
  16.     CALL FUNCTION 'F4IF_INT_TABLE_VALUE_REQUEST'
  17.       EXPORTING
  18.         retfield        = 'LGORT'            "筛选内表里面的字段
  19.         dynpprog        = sy-repid
  20.         dynpnr          = sy-dynnr
  21.         dynprofield     = 'GS_OUTPUT-LGORT'            "ALV内表字段
  22.         value_org       = 'S'
  23.   "     CALLBACK_PROGRAM = SY-REPID
  24.       TABLES
  25.         value_tab       = lt_t001l        "需要显示帮助的值内表
  26.         return_tab      = lt_return          "返回值
  27.       EXCEPTIONS
  28.         parameter_error = 1
  29.         no_values_found = 2
  30.         OTHERS          = 3.
  31. * 将搜索帮助选中的返回值写到ALV上
  32.     IF sy-subrc = 0.
  33.       READ TABLE lt_return INTO ls_return INDEX 1.
  34.       IF ls_return-fieldval IS NOT INITIAL .
  35.         <fs_opt>-lgort = ls_return-fieldval.
  36.       ENDIF.
  37.     ENDIF.
  38.   ENDIF.
  40. ENDFORM.

效果：

image.png