SimpleTiles - 图1

    1. // Tiles, Bricks and other Patterns
    2. // SimpleTiles.osl, by Zap Andersson
    3. // Modified: 2019-11-25
    4. // Copyright 2019 Autodesk Inc, All rights reserved. This file is licensed under Apache 2.0 license
    5. //    https://github.com/ADN-DevTech/3dsMax-OSL-Shaders/blob/master/LICENSE.txt
    8. #define PARAM lookup,fluvw+point(xx,0,0),GapWidth*0.05,Tiling,Edge*0.1,Bump,HitIdx
    10. // Do a single rectangle        
    11. int doRect(float loX, float hiX, float loY, float hiY, int Tile, int InIdx, float Radius,
    12.     // Layout of these match the PARAM macro above
    13.     point uvw, point baseuvw, float GapWidth, vector Tiling, float Edge, output float Bump, output int Index
    14. )
    15. {
    16.     float x = uvw[0] / Tiling[0], y = uvw[1] / Tiling[1];    
    18.     float lox = loX / Tiling[0];
    19.     float hix = hiX / Tiling[0];    
    20.     float loy = loY / Tiling[1];
    21.     float hiy = hiY / Tiling[1];    
    24.     // First quick rejection when being outside the rectangle    
    25.     if (x < lox + GapWidth || 
    26.         x > hix - GapWidth || 
    27.         y < loy + GapWidth ||
    28.         y > hiy - GapWidth)
    29.         return 0;
    31.     // Turn coordinate into circle
    32.     float gwr = GapWidth + Radius;    
    34.     float lx = x - (lox + gwr);
    35.     float ly = y - (loy + gwr);
    36.     float hx = x - (hix - gwr);
    37.     float hy = y - (hiy - gwr);
    39.     // Now compute special-circle-coordinate
    40.     // which is really the edges around the rectangle
    41.     vector dp = vector(lx<0?lx:(hx>0?hx:0.0), ly<0?ly:(hy>0.0?hy:0.0), 0.0);    
    42.     float  d = length(dp);    
    43.     // Outside the radius - we missed
    44.     if (d > Radius) return 0;
    46.     // Inside? Compute the bump as a Smoothstep        
    47.     if (Radius > Edge)    
    48.         Bump = 1.0 - smoothstep(Radius-Edge, Radius+Edge, d);
    49.     else
    50.     {
    51.         // If there is an Edge but the radius is smaller, we
    52.         // need to compute the bump differently...
    53.         float lx = x - (lox + GapWidth);
    54.         float ly = y - (loy + GapWidth);
    55.         float hx = x - (hix - GapWidth);
    56.         float hy = y - (hiy - GapWidth);        
    57.         Bump  = smoothstep(-Edge, Edge,  lx);
    58.         Bump *= smoothstep(-Edge, Edge, -hx);
    59.         Bump *= smoothstep(-Edge, Edge,  ly);
    60.         Bump *= smoothstep(-Edge, Edge, -hy);
    61.     }
    63.     // Set index to inIdx
    64.     Index = InIdx;
    65.     // Return the tile ID we are in    
    66.     return Tile;
    67. }
    69. shader SimpleTiles
    70.     [[ string help  = "<font size=+1><b>Simple Tiles</b></font><br>"
    71.         "Allows various kinds of Tiling. The Tiling Offset<br>"
    72.         "modifies the base parameter of the tiling layout,<br>" 
    73.         "and can generate different effects. ",
    74.        string category = "Textures",
    75.        string label = "Simple Tiles" ]]
    76. (
    77.     // Inputs
    78.     point UVW = point(u,v,0),
    80.     float Scale   = 1.0
    81.         [[ float min=0.000001, float max=1000000.0 ]], 
    82.     int   TileMode  = 0 
    83.         [[ string widget  = "mapper", 
    84.            string label   = "Tiling Mode",
    85.            string options = 
    86.                "Checker Tiles:1"
    87.                "|Running/Stack Bond:0"
    88.                "|English Bond:2"
    89.                "|Fine Running/Stack Bond:3"
    90.                "|Twist Box:4",
    91.            string help="Choose the kind of tile pattern to use. "
    92.                        "The 'TilingOffset' parameter adjusts the "
    93.                        "appearance of the tiles."
    94.            ]],        
    95.     float U_Count = 2.0
    96.         [[ string label = "Tiles in U",
    97.              float min=0.000001, float max=1000000.0 ]], 
    98.     float V_Count = 2.0    
    99.         [[ string label = "Tiles in V",
    100.              float min=0.000001, float max=1000000.0 ]], 
    101.     float TilingOffset = 0.5
    102.         [[ string label = "Tiling Offset",
    103.              float min=0.0, float max=1.0,
    104.              string help = "An adjustable parameter which changes "
    105.                  "the appearance of the tiling. Does different things "
    106.                 "for different Tiling Modes" ]], 
    107.     float GapWidth   = 0.1
    108.         [[ string label = "Gap Width",
    109.            string help  = "The width of the gap between tiles",
    110.              float min=0.0, float max=10.0 ]], 
    111.     float Radius  = 0.2
    112.         [[ string label = "Corner Roundness",
    113.            string help  = "Adds fillet radius to the corner of the tiles",
    114.              float min=0.0, float max=10.0 ]], 
    115.     float Edge      = 0.1
    116.         [[ string label = "Edge Width (for Bump)",
    117.            string help  = "The width of a (slightly beveled) fake 'Edge' "
    118.                           "to give the tile a more realistic appearance",
    119.              float min=0.0, float max=10.0 ]],     
    120.     float EdgeBump = 1.0
    121.         [[ float min=-10.0, float max=10.0,
    122.            string help  = "The amount of Edge bump effect" ]],    
    123.     float ColorBump = 0.0
    124.         [[ float min=-10.0, float max=10.0,
    125.            string help  = "Adds some contribution of the color "
    126.                           "settings to the Bump output" ]],        
    127.     color GapColor   = 0.2
    128.         [[ string label = "Gap Color", 
    129.            string help  = "The color of the gap between tiles" ]], 
    130.     color TileColor1 = 0.4
    131.         [[ string label = "Tile Color 1",
    132.            string help  = "First Tile Color"
    133.          ]], 
    134.     color TileColor2 = 0.5
    135.         [[ string label = "Tile Color 2",
    136.            string help  = "Second Tile Color"
    137.          ]], 
    138.     color TileColor3 = 0.6
    139.         [[ string label = "Tile Color 3",
    140.            string help  = "Third Tile Color. Not all Tiling Modes use this."        
    141.          ]], 
    143.     // Outputs
    144.     output color Col = 0.0,
    145.     output float Bump = 0.0,
    146.     output int   Tile = 0,
    147.     output int   TileIdx = 0,
    148.     output int   Index = 0    
    149. )
    150. {
    151.     int   Overlap   = 1;    
    152.     vector Tiling = vector(U_Count, V_Count, 0.0);
    153.     Col = GapColor;
    154.     point uvw = UVW * Tiling / Scale;
    155.     float to = TilingOffset;
    156.     float to2 = to*0.5;
    158.     float Roundness = Radius / 10.0;
    160.     // Floor of UVW    
    161.     point fluvw = floor(uvw);
    162.     // Fractional UVW
    163.     point fruvw = uvw - fluvw;
    165.     // Loop over neighbours
    166.     for (int xx = -Overlap; xx <= 0; xx++)
    167.     {
    168.         point lookup = uvw - fluvw - point(xx,0,0);
    169.         int   HitIdx = 0;
    170.         // Running Bond
    171.         if (TileMode == 0)
    172.         {
    173.             if (Tile == 0) 
    174.                 Tile = doRect(0.0 ,1.0, 0.0, 0.5, 1, 1, Roundness, PARAM);
    175.             if (Tile == 0) 
    176.                 Tile = doRect(to, to+1.0, 0.5, 1.0, 2, 2, Roundness, PARAM);
    177.         }
    178.         // Stack Bond
    179.         if (TileMode == 1)
    180.         {
    181.             if (Tile == 0) 
    182.                 Tile = doRect(0.0 ,0.5, 0.0, 0.5, 1, 1, Roundness, PARAM);
    183.             if (Tile == 0) 
    184.                 Tile = doRect(0.0, 0.5, 0.5, 1.0, 2, 2, Roundness, PARAM);
    185.             if (Tile == 0) 
    186.                 Tile = doRect(0.5 ,1.0, 0.0, 0.5, 2, 3, Roundness, PARAM);
    187.             if (Tile == 0) 
    188.                 Tile = doRect(0.5, 1.0, 0.5, 1.0, 1, 4, Roundness, PARAM);
    189.         }
    190.         // English Bond
    191.         if (TileMode == 2)
    192.         {
    193.             if (Tile == 0) 
    194.                 Tile = doRect(0.0 ,1.0, 0.0, 0.5, 1, 1, Roundness, PARAM);
    195.             if (Tile == 0) 
    196.                 Tile = doRect(0.0+to2, 0.5+to2, 0.5, 1.0, 2, 2, Roundness, PARAM);
    197.             if (Tile == 0) 
    198.                 Tile = doRect(0.5+to2, 1.0+to2, 0.5, 1.0, 2, 3, Roundness, PARAM);
    199.         }
    200.         // Fine Running Bond
    201.         if (TileMode == 3)
    202.         {
    203.             if (Tile == 0) 
    204.                 Tile = doRect(0.0 ,1.0, 0.0, 0.5, 1, 1, Roundness, PARAM);
    205.             if (Tile == 0) 
    206.                 Tile = doRect(0.0+to, 0.5+to, 0.5, 0.75, 2, 2, Roundness, PARAM);
    207.             if (Tile == 0) 
    208.                 Tile = doRect(0.5+to, 1.0+to, 0.5, 0.75, 2, 3, Roundness, PARAM);
    209.             if (Tile == 0) 
    210.                 Tile = doRect(0.0+to2, 0.5+to2, 0.75, 1.0, 3, 4, Roundness, PARAM);
    211.             if (Tile == 0) 
    212.                 Tile = doRect(0.5+to2, 1.0+to2, 0.75, 1.0, 3, 5, Roundness, PARAM);
    213.         }
    214.         // Twist Box
    215.         if (TileMode == 4)
    216.         {
    217.             if (Tile == 0) 
    218.                 Tile = doRect(0.0, 1.0-to2, 0.0, to2, 1, 1, Roundness, PARAM);
    219.             if (Tile == 0) 
    220.                 Tile = doRect(to2, 1.0, 1.0-to2, 1.0, 1, 2, Roundness, PARAM);
    221.             if (Tile == 0) 
    222.                 Tile = doRect(0.0, to2, to2, 1.0, 2, 3, Roundness, PARAM);
    223.             if (Tile == 0) 
    224.                 Tile = doRect(1.0-to2, 1.0, 0.0, 1.0-to2, 2, 4, Roundness, PARAM);
    225.             if (Tile == 0) 
    226.                 Tile = doRect(to2, 1.0-to2, to2, 1.0-to2, 3, 5, Roundness, PARAM);
    227.         }
    228.         if (HitIdx > 0)
    229.         {
    230.             TileIdx = HitIdx;
    231.             Index = HitIdx + int((float)cellnoise(fluvw+point(xx,0,0)) * 1024.0);
    232.         }
    233.     }
    235.     if (Tile == 1) Col = TileColor1;        
    236.     if (Tile == 2) Col = TileColor2;
    237.     if (Tile == 3) Col = TileColor3;
    239.     Bump *= EdgeBump;    
    240.     Bump += dot(0.3333, Col) * ColorBump;
    241. }