1.    In the collected ABNF below, list rules are expanded as per Section 1.2 of [RFC7230].
    3.    Accept-Ranges = acceptable-ranges
    5.    Content-Range = byte-content-range / other-content-range
    7.    HTTP-date = <HTTP-date, see [RFC7231], Section 7.1.1.1>
    9.    If-Range = entity-tag / HTTP-date
    11.    OWS = <OWS, see [RFC7230], Section 3.2.3>
    13.    Range = byte-ranges-specifier / other-ranges-specifier
    15.    acceptable-ranges = ( *( "," OWS ) range-unit *( OWS "," [ OWS range-unit ] ) ) / "none"
    17.    byte-content-range = bytes-unit SP ( byte-range-resp / unsatisfied-range )
    18.    byte-range = first-byte-pos "-" last-byte-pos
    19.    byte-range-resp = byte-range "/" ( complete-length / "*" )
    20.    byte-range-set = *( "," OWS ) ( byte-range-spec / suffix-byte-range-spec ) *( OWS "," [ OWS ( byte-range-spec / suffix-byte-range-spec ) ] )
    21.    byte-range-spec = first-byte-pos "-" [ last-byte-pos ]
    22.    byte-ranges-specifier = bytes-unit "=" byte-range-set
    23.    bytes-unit = "bytes"
    25.    complete-length = 1*DIGIT
    27.    entity-tag = <entity-tag, see [RFC7232], Section 2.3>
    29.    first-byte-pos = 1*DIGIT
    31.    last-byte-pos = 1*DIGIT
    33.    other-content-range = other-range-unit SP other-range-resp
    34.    other-range-resp = *CHAR
    35.    other-range-set = 1*VCHAR
    36.    other-range-unit = token
    37.    other-ranges-specifier = other-range-unit "=" other-range-set
    39.    range-unit = bytes-unit / other-range-unit
    41.    suffix-byte-range-spec = "-" suffix-length
    43.    suffix-length = 1*DIGIT
    45.    token = <token, see [RFC7230], Section 3.2.6>
    47.    unsatisfied-range = "*/" complete-length