1. chunk ::= {stat [`;´]} [laststat [`;´]]
    3. block ::= chunk
    5. stat ::=  varlist `=´ explist | 
    6.          functioncall | 
    7.          do block end | 
    8.          while exp do block end | 
    9.          repeat block until exp | 
    10.          if exp then block {elseif exp then block} [else block] end | 
    11.          for Name `=´ exp `,´ exp [`,´ exp] do block end | 
    12.          for namelist in explist do block end | 
    13.          function funcname funcbody | 
    14.          local function Name funcbody | 
    15.          local namelist [`=´ explist] 
    17. laststat ::= return [explist] | break
    19. funcname ::= Name {`.´ Name} [`:´ Name]
    21. varlist ::= var {`,´ var}
    23. var ::=  Name | prefixexp `[´ exp `]´ | prefixexp `.´ Name 
    25. namelist ::= Name {`,´ Name}
    27. explist ::= {exp `,´} exp
    29. exp ::=  nil | false | true | Number | String | `...´ | function | 
    30.          prefixexp | tableconstructor | exp binop exp | unop exp 
    32. prefixexp ::= var | functioncall | `(´ exp `)´
    34. functioncall ::=  prefixexp args | prefixexp `:´ Name args 
    36. args ::=  `(´ [explist] `)´ | tableconstructor | String 
    38. function ::= function funcbody
    40. funcbody ::= `(´ [parlist] `)´ block end
    42. parlist ::= namelist [`,´ `...´] | `...´
    44. tableconstructor ::= `{´ [fieldlist] `}´
    46. fieldlist ::= field {fieldsep field} [fieldsep]
    48. field ::= `[´ exp `]´ `=´ exp | Name `=´ exp | exp
    50. fieldsep ::= `,´ | `;´
    52. binop ::= `+´ | `-´ | `*´ | `/´ | `^´ | `%´ | `..´ | 
    53.    `<´ | `<=´ | `>´ | `>=´ | `==´ | `~=´ | 
    54.    and | or
    56. unop ::= `-´ | not | `#´