HttpDemo

/// yx
/// 示例Url = http://192.168.1.21/dthealth/web/csp/pha.mob.broker.csp
/// w ##class(Demo.HttpDemo).HttpGetDemo()
ClassMethod HttpGetDemo()
{
    /* 定义request对象 */
    #dim request as %Net.HttpRequest= ##class(%Net.HttpRequest).%New()
    /* 请求地址不用加http:// */
    s request.Server ="192.168.1.21"
    /* Timeout指定等待web服务器响应的时间，以秒为单位。 缺省值是30秒。 */
    s request.Timeout = 5
    /* WriteTimeout指定等待Web服务器完成写入的时间(以秒为单位)。默认情况下，它将无限期等待。可接受的最小值为2秒。 */
    s request.WriteTimeout = 5
    /* 添加地址对象参数 */
    d request.InsertParam("CacheUserName", "yx")
    d request.InsertParam("CachePassword", "123456")
    d request.InsertParam("CacheNoRedirect", "1")
    d request.InsertParam("ClassName", "PHA.PCCP.MOB.API")
    d request.InsertParam("MethodName", "GetPhaWardRound")
    d request.InsertParam("params", "172#O")
    /* 设置cookies 防止占用多个lic */
    d:($g(%cookies) '= "") request.SetHeader("cookie", %cookies)
    /* 请求地址路径 */
    s status = request.Get("/dthealth/web/csp/pha.mob.broker.csp")
    if (status '= 1) {
        d $System.Status.DisplayError(status) 
        q "请求失败"
    }
    /* 定义response对象 */
    #dim response as %Net.HttpResponse  = request.HttpResponse
    /* 获取HTTP状态码 */
    s statusCode= response.StatusCode
    if (statusCode = 200){
        /* 获取头信息两种方式(一) */
        s encoding = response.GetHeader("CONTENT-ENCODING")
        /* 获取头信息两种方式(二) */
        s cookie = response.Headers("SET-COOKIE")
        s %cookies = $p(cookie, ";", 1)
        w "输出所有头部信息：",!
        d response.OutputHeaders()
        w !
        /* 获取流数据 */
        #dim stream as  %GlobalBinaryStream = response.Data
        s data = stream.Read()
    }
    q $g(data)
}