Hexagon - 图1

    1. /*
    2.  * Hexagon.osl by Michel J. Anders (c)2012
    3.  * from https://github.com/sambler/osl-shaders
    4.  *
    5.  * license: cc-by-sa
    6.  *
    7.  * original script from -
    8.  * http://blenderthings.blogspot.co.uk/2012/11/a-hexagon-osl-shader.html
    9.  * Modified 1/4/2020 by Saul Espinosa for Redshift 3D
    10.  */
    13. #define A 0.86602540378443864676372317075294 // sqrt(3)/2
    14. #define A2 (2*A)
    15. #define A4 (4*A)
    16. #define SY (1/A)
    18. shader MAhexagon
    19. [[  string help = "Generates an RGB Hexagon Pattern",
    20.     string label = "Hexagons" ]]
    21. (
    22.         vector Vector = 0,
    23.         color Diffuse_Color1 = color(0.2, 0.8, 0.2),
    24.         color Diffuse_Color2 = color(0.8, 0.2, 0.2),
    25.         color Diffuse_Color3 = color(0.2, 0.2, 0.8),
    26.         output color Color = 0,
    27.         output int Index = 1,
    28.         output float Distance = 0)
    29. {
    30.     // calculate the color
    32.     color colors[3] = {Diffuse_Color1,
    33.                        Diffuse_Color2,
    34.                        Diffuse_Color3};
    36.     // we warp the grid so that two adjacent equilateral triangles
    37.     // are mapped to two triangles that fit in a square
    38.     float syc = Vector[1] * SY;
    39.     float sxc = Vector[0] + 0.5 * syc;
    41.     int ind[18] = {1,1,3,3,3,1, 2,2,2,3,3,3, 1,2,2,2,1,1};
    43.     int iy = int(mod(syc,3.0));
    44.     int ix = int(mod(sxc,3.0));
    45.     ix = iy * 6 + ix * 2 + ( mod(sxc,1.0) > mod(syc,1.0) );
    46.     Index = ind[ix];
    47.     Color = colors[Index-1];
    49.     // calculate the distance to the center of the hexagon
    51.     float sx = mod(Vector[0],3);
    52.     float sy = mod(Vector[1]+0.75,A4);
    54.     // map everthing to a single quadrant
    55.     if ( sx > 1.5 ) sx = 3 - sx;
    56.     if ( sy > A2 ) sy = A4 - sy;
    58.     // the distance were interested in is the distance to
    59.     // the *closest* center point
    60.     float d1 = distance(vector(sx,sy,0),vector(1.5,A2,0));
    61.     float d2 = distance(vector(sx,sy,0),vector(0,A,0));
    62.     float d6 = distance(vector(sx,sy,0),vector(1.5,0,0));
    64.     Distance = min(min(d1,d2), d6);
    66. }